directman

Интеграция датчика Mi flora plant к системе УД MAJORDOMO

В тему будущего шлюза BLE, для начала попробуем интегрировать одно из устроств.
Это заготовок статьи.

Итак, для интеграции BLE устройства Mi flora plant нам потребуется микроконтроллер ESP32, желательно с уже интегрированными портами micro-USB. Например такой
https://ru.aliexpress.com/item/ESP32-ESP-32S-ESP-3...
или такой
https://ru.aliexpress.com/item/LoRa-ESP32-0-96-Inc...

Далее нам необходимо скачать и установить Arduino ide

https://www.arduino.cc/en/main/software#

выбираем Windows Installer, for Windows XP and up, скачиваем и устанавливаем в папку, в которую потом можно будет легко настроть доступ. Желательно C:\arduino.

Далее нам понадобится библиотека espressif для работы с ESP32

Для корректной ее установки мне потребовался GIT для windows.
https://git-scm.com/download/win

Настраиваем его, если из командной строки git недоступен, необходимо путь до папки директории C:\Program Files\git\bin\ прописать в %PATH%

Если вы работаете через прокси, то его необходимо прописать
git config --global http.proxy http://proxyUsername:proxyPassword@proxy.server.co...

теперь по инструкции https://github.com/espressif/arduino-esp32/blob/ma... устанавливаем библотеку arduino-esp32

Выбираем в Инструменты -> Менеджер плат -> ESP32 Dev mod.
Выбираем COM порт, который появился при подключении ESP32 к компьютеру (у меня COM3)

Теперь пробуем откомпилить самый простой пример:
Файл-> Примеры -> WIFI -> ScanNetworks.
Открываем пример, компилируем и проверяем работоспособность.

Если все хорошо, то после копмиляции в окне Инструменты - > Монитор порта мы увидим список сетей WIFI.

Для работы с MI FLORA нам понадобится скетч https://github.com/sidddy/flora, скачиваем его с GIT например по ссылке https://github.com/sidddy/flora/archive/master.zip

Распаковываем в директорию C:/aduino/miplant/
Переименовываем файл config.h.example в config.h и правим в нем свои настройки wifi, сервера mqtt и тд.

Для компиляции это скетча пришлось подключить библиотеку PubSub:
Скетч -> Подключить библиотеку > PubSub -> Install.

Далее необходимо изменить размер скетча:
Инструменты - > Partrition Scmeme -> No OTA (Large APP)

Все скетч готов, можно заливать в плату.

Если нам нужна поддержка экрана, то необходимо скачать библоотеку из инструкции https://www.alictronix.com/archives/817

Готовая папка Arduino https://yadi.sk/d/2dg_xPLS3ZEmun, скачать, если не хвататет каких-либо библиотек.

Пока тестирую готовый скетч,
Планы на будщее:
1) вывод информации на экран LORA
2) добавить поддерку весов GASON S4 https://ru.aliexpress.com/item/GASON-S4-Body-Fat-S...
3) добавить поддерку чайника XIAOMI.

На всякий случай (для себя) приведу свой код для работы с экраном

/**
   A BLE client for the Xiaomi Mi Plant Sensor, pushing measurements to an MQTT server.

   MIT License

   Copyright (c) 2017 Sven Henkel

   Permission is hereby granted, free of charge, to any person obtaining a copy
   of this software and associated documentation files (the "Software"), to deal
   in the Software without restriction, including without limitation the rights
   to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   copies of the Software, and to permit persons to whom the Software is
   furnished to do so, subject to the following conditions:

   The above copyright notice and this permission notice shall be included in all
   copies or substantial portions of the Software.

   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
   IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
   FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
   AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
   LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
   OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
   SOFTWARE.
*/

#include "BLEDevice.h"
#include <WiFi.h>
#include <PubSubClient.h>
#include "config.h"

#include <Wire.h>  // Only needed for Arduino 1.6.5 and earlier
#include "SSD1306.h" // alias for `#include "SSD1306Wire.h"`
#include "images.h"

SSD1306  display(0x3c, 4, 15);

int demoMode = 0;
int counter = 1;

RTC_DATA_ATTR int bootCount = 0;

// The remote service we wish to connect to.
static BLEUUID serviceUUID("00001204-0000-1000-8000-00805f9b34fb");

// The characteristic of the remote service we are interested in.
static BLEUUID uuid_version_battery("00001a02-0000-1000-8000-00805f9b34fb");
static BLEUUID uuid_sensor_data("00001a01-0000-1000-8000-00805f9b34fb");
static BLEUUID uuid_write_mode("00001a00-0000-1000-8000-00805f9b34fb");

static BLEAddress floraAddress(FLORA_ADDR);

static int doConnect = 0;
static boolean connected = false;
static BLERemoteCharacteristic* pRemoteCharacteristic;

WiFiClient espClient;
PubSubClient client(espClient);

bool getSensorData(BLEAddress pAddress, bool getBattery) {
  Serial.print("Forming a connection to Flora device at ");
  Serial.println(pAddress.toString().c_str());

  BLEClient*  pClient  = BLEDevice::createClient();

  // Connect to the remove BLE Server.
  if (!pClient->connect(pAddress)) {
      return false;
  }
  Serial.println(" - Connected to Flora");

  // Obtain a reference to the service we are after in the remote BLE server.
  BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
  if (pRemoteService == nullptr) {
    Serial.print("Failed to find our service UUID: ");
    Serial.println(serviceUUID.toString().c_str());
    return false;
  }
  Serial.println(" - Found our service");

  pRemoteCharacteristic = pRemoteService->getCharacteristic(uuid_write_mode);
  uint8_t buf[2] = {0xA0, 0x1F};
  pRemoteCharacteristic->writeValue(buf, 2, true);

  delay(500);

  // Obtain a reference to the characteristic in the service of the remote BLE server.
  pRemoteCharacteristic = pRemoteService->getCharacteristic(uuid_sensor_data);
  Serial.println(pRemoteService->toString().c_str());
  if (pRemoteCharacteristic == nullptr) {
    Serial.print("Failed to find our characteristic UUID: ");
    Serial.println(uuid_sensor_data.toString().c_str());
    return false;
  }
  Serial.println(" - Found our characteristic");

  // Read the value of the characteristic.
  std::string value = pRemoteCharacteristic->readValue();
  Serial.print("The characteristic value was: ");
  const char *val = value.c_str();

  Serial.print("Hex: ");
  for (int i = 0; i < 16; i++) {
    Serial.print((int)val[i], HEX);
    Serial.print(" ");
  }
  Serial.println(" ");

  float temp = (val[0] + val[1] * 256) / ((float)10.0);
  int moisture = val[7];
  int light = val[3] + val[4] * 256;
  int conductivity = val[8] + val[9] * 256;

  char buffer[64];

  Serial.print("Temperature: ");
  Serial.println(temp);
  snprintf(buffer, 64, "%f", temp);
  client.publish(MQTT_TEMPERATURE, buffer);

  Serial.print("Moisture: ");
  Serial.println(moisture);
  snprintf(buffer, 64, "%d", moisture);
  client.publish(MQTT_MOISTURE, buffer);

  Serial.print("Light: ");
  Serial.println(light);
  snprintf(buffer, 64, "%d", light);
  client.publish(MQTT_LIGHT, buffer);

  Serial.print("Conductivity: ");
  Serial.println(conductivity);
  snprintf(buffer, 64, "%d", conductivity);
  client.publish(MQTT_CONDUCTIVITY, buffer);

  if (getBattery) {
    Serial.println("Trying to retrieve battery level...");
    pRemoteCharacteristic = pRemoteService->getCharacteristic(uuid_version_battery);
    if (pRemoteCharacteristic == nullptr) {
      Serial.print("Failed to find our characteristic UUID: ");
      Serial.println(uuid_sensor_data.toString().c_str()); 
      return false;
    }
    Serial.println(" - Found our characteristic");

    // Read the value of the characteristic...
    value = pRemoteCharacteristic->readValue();
    Serial.print("The characteristic value was: ");
    const char *val2 = value.c_str();
    Serial.print("Hex: ");
    for (int i = 0; i < 16; i++) {
      Serial.print((int)val2[i], HEX);
      Serial.print(" ");
    }
    Serial.println(" ");

    int battery = val2[0];
    Serial.print("Battery: ");
    Serial.println(battery);
    snprintf(buffer, 64, "%d", battery);
    client.publish(MQTT_BATTERY, buffer);
  }

  pClient->disconnect();
}

void taskDeepSleep( void * parameter )
{
  delay(SLEEP_WAIT * 1000);
  esp_sleep_enable_timer_wakeup(SLEEP_DURATION * 1000000ll);
  Serial.println("Going to sleep now.");
  esp_deep_sleep_start();
}

void setup() {

  /* disp */

  pinMode(16,OUTPUT);
  digitalWrite(16, LOW);    // set GPIO16 low to reset OLED
  delay(50); 
  digitalWrite(16, HIGH); // while OLED is running, must set GPIO16 in high

  // Initialising the UI will init the display too.
  display.init();

  display.flipScreenVertically();
  display.setFont(ArialMT_Plain_10);

/* */

  Serial.begin(115200);
  delay(1000);

  xTaskCreate(      taskDeepSleep,          /* Task function. */
                    "TaskDeepSleep",        /* String with name of task. */
                    10000,                  /* Stack size in words. */
                    NULL,                   /* Parameter passed as input of the task */
                    1,                      /* Priority of the task. */
                    NULL);                  /* Task handle. */

    display.setTextAlignment(TEXT_ALIGN_LEFT);
    display.setFont(ArialMT_Plain_10);
    display.clear();

  String text = "Starting Flora client...";
  Serial.println(text);

    display.drawString(0, 0, text);
    display.display();

  BLEDevice::init("");

  text = "Connecting WiFi...";
  Serial.println(text);
  display.drawString(0, 10, text);
  display.display();  
  WiFi.begin(wifi_ssid, wifi_password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
 text = "WiFi connected";
  Serial.println(text);
  display.drawString(0, 20, text);
  display.display();  

  client.setServer(mqtt_server, 1883);
  while (!client.connected()) {
    text = "Attempting MQTT connection...";
    Serial.print(text);
display.drawString(0, 30, text);    
display.display();  
    // Attempt to connect
    if (client.connect("floraClient")) {
 text = "connected";      
      Serial.println(text);
    display.drawString(0, 30, text);    
    display.display();  

    } else {
      text = "failed, rc="+String(client.state())+"try again in 5 seconds";      
      //Serial.print("failed, rc=");
      //Serial.print(client.state());
      //Serial.println(" try again in 5 seconds");
      Serial.println(text);
      display.clear();
    display.drawString(0, 0, text);    
    display.display();        
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }

  delay(1000);

  getSensorData(floraAddress, ((bootCount % BATTERY_INTERVAL) == 0));
  bootCount++;
} // End of setup.

// This is the Arduino main loop function.
void loop() {
  delay(10000);
} // End of loop

Обсуждение (0) (11)

Екатеринбург, Россия

На форуме: directman66